TEXT funksiyasi
TEXT() funksiyasi yordamida formatlashni qo‘llash orqali son yoki sana qanday ko‘rsatilishini o‘zgartirishingiz mumkin.
Sonlarni formatlash
TEXT funksiyasi sonlarni berilgan formatga muvofiq formatlaydi. Masalan, A ustunida 23.7825 soni bo‘lsa va uni kasrdan keyin uchta raqam bilan ko‘rsatish kerak bo‘lsa, quyidagi formuladan foydalaning:
TEXT(A;".3f")
Natijada "23.783" satri hosil bo‘ladi.
Format:
TEXT(number;string_format)
Satr formati:
Satr formati quyidagicha yoziladi: [flags][width][.precision]conversion
- [flags] — formatlash uchun maxsus belgilar. Masalan, "+" belgisi son qiymatida + belgisi bo‘lishi kerakligini; "-" belgisi natija chap tomonga tekislanishini; "," belgisi esa butun sonlarda mingliklar ajratgichi qo‘yilishini bildiradi. Bu parametr majburiy emas.
- [width] — ko‘rsatiladigan belgilarning minimal sonini belgilovchi musbat butun son. Bu parametr majburiy emas.
- [.precision] — oldidan o‘nli nuqta qo‘yilgan noldan kichik bo‘lmagan butun son. Odatda belgilar sonini cheklash uchun ishlatiladi. Bu parametr majburiy emas.
- conversion — son qanday formatlanishini bildiruvchi belgi. Butun sonlar uchun d, kasr sonlar uchun f ishlatiladi. Bu parametr majburiy.
Masalan, "Number" deb nomlangan maydonda 12.34 soni bor deb olaylik:
- TEXT({{Task.Number field}};"d") — natija: 12
- TEXT({{Task.Number field}};"05d") — natija: 00012
- TEXT({{Task.Number field}};"08.3f") — natija: 0012.340
- TEXT({{Task.Number field}};".4f") — natija: 12.3400
Misollar:
TEXT(A;".3f")
TEXT({{Task.Number field}};".3f")
TEXT(1234567; ",.2f") — natija: 12 345,67
Sanalarni formatlash
Quyida sanani formatlash uchun formulalar jadvali keltirilgan. Misolda 2016-yil 12-oktabr sanasi formatlangan.
| Nimani ko‘rsatish | Ko‘rinishi | Format | Formula | Natija |
| Oylar | 1-12 | "M" | TEXT(A;"M") | 10 |
| Oylar | 01-12 | "MM" | TEXT(A;"MM") | 10 |
| Oylar | Jan-Dec | "MMM" | TEXT(A;"MMM") | Oct |
| Oylar | January-December | "MMMM" | TEXT(A;"MMMM") | October |
| Oylar | J-D | "MMMMM" | TEXT(A;"MMMMM") | O |
| Kunlar | 1-31 | "D" | TEXT(A;"D") | 12 |
| Kunlar | 01-31 | "DD" | TEXT(A;"DD") | 12 |
| Kunlar | Mon-Sun | "DDD" | TEXT(A;"DDD") | Wed |
| Kunlar | Monday-Sunday | "DDDD" | TEXT(A;"DDDD") | Wednesday |
| Yillar | 00-99 | "YY" | TEXT(A;"YY") | 16 |
| Yillar | 1900-9999 | "YYYY" | TEXT(A;"YYYY") | 2016 |
Funksiya oy nomini qaratqich kelishigida chiqarishi uchun quyidagi sintaksisdan foydalaning:
TEXT(number; "[$-xxx]date format")
Bu yerda xxx — til kodi:
- FC19 — rus tili
- FC22 — ukrain tili
- 409 — ingliz tili
Misol:
TEXT({{System.Today}}; "[$-FC19]DD MMMM YYYY")
Natija:
14 июня 2022
Vaqtni formatlash
Quyida vaqtni formatlash uchun formulalar jadvali keltirilgan. Misolda 14:22:44 vaqti formatlangan.
| Nimani ko‘rsatish | Ko‘rinishi | Format | Formula | Natija |
| Soatlar | 0-23 | "H" | TEXT(A;"H") | 14 |
| Soatlar | 00-23 | "HH" | TEXT(A;"HH") | 14 |
| Daqiqalar | 0-59 | "m" | TEXT(A;"m") | 22 |
| Daqiqalar | 00-59 | "mm" | TEXT(A;"mm") | 22 |
| Soniyalar | 0-59 | "s" | TEXT(A;"s") | 44 |
| Soniyalar | 00-59 | "ss" | TEXT(A;"ss") | 44 |
| Vaqt | 14:00 | "HH:00" | TEXT(A;"HH:00") | 14:00 |
| Vaqt | 14:22 | "HH:mm" | TEXT(A;"HH:mm") | 14:22 |
| Vaqt | 14:22:44 | "HH:mm:ss" | TEXT(A;"HH:mm:ss") | 14:22:44 |
| Vaqt | 14:22:44,11 | "HH:mm:ss,00" | TEXT(A;"HH:mm:ss,00") | 14:22:44,11 |
| Sarflangan vaqt (soat va daqiqalar) | 1:02 | "[H]:mm" | TEXT(A;"[H]:mm") | 1:02 |
| Sarflangan vaqt (daqiqalar va soniyalar) | 62:16 | "[mm]:ss" | TEXT(A;"[mm]:ss") | 62:16 |
| Sarflangan vaqt (soniyalar va soniyaning yuzdan bir ulushi) | 3735,80 | "[ss],00" | TEXT(A;"[ss],00") | 3735,80 |
Muhim
- Vaqt va sana orasida bo‘sh joy bo‘lishi kerak.
- Vaqt qismlari ":" belgisi bilan, millisekundlar esa "," belgisi bilan ajratiladi. Masalan: 23:15:41,456.
- Sanalar ".", "/" yoki "-" belgilaridan biri bilan ajratiladi.
- Agar sana ko‘rsatilmagan bo‘lsa, standart qiymat 01.01.1900 bo‘ladi.
- Sana formati satri ancha moslashuvchan (istalgan satrni kiritish mumkin, ayrim belgilar vaqt birliklari bilan almashtiriladi). Maxsus belgilar — D, M, Y, H, m, s — vaqt birligi sifatida emas, harf sifatida ko‘rsatilishi uchun ularni ekranlash kerak.
- Davomiylikni soat/daqiqa/soniya ko‘rinishida chiqarish mumkin (agar faqat sana ko‘rsatilgan bo‘lsa, 31.12.1899 sanasidan beri o‘tgan vaqt ko‘rsatiladi. Demak, 01.01.1900 sanasi uchun soatlardagi davomiylik 24 ga teng).
- Ikki raqam bilan ko‘rsatilgan yil 21-asrga tegishli deb hisoblanadi.
- Agar format satrida teskari qiya chiziq "\" kerak bo‘lsa, uni "\\" ko‘rinishida ekranlash kerak. Bu, ayniqsa, satr oxirida kelganda muhim.
- Agar format d/f bilan tugasa va sana kerak bo‘lsa, d/f belgisini ekranlash kerak. Masalan, TEXT("12.05.2018"; "\Hello World") quyidagi qiymatni qaytaradi: Hello World.